易语言制作pc蛋蛋预测软件教程源码

本次教程教大家用易语言做一款pc蛋蛋预测软件的教程，最后会附上源码，仅供学习使用。

1、画好界面，这个可以自己画或者参考我的也可以。

2、做一个模块，功能就是获取网页数据并处理开奖数据，取到我们需要的数据，源码如下：

.版本 2
.支持库 internet
.支持库 RegEx

.程序集 网页开奖数据

.子程序 读入网站数据, 文本型, 公开
.局部变量 局_文本, 文本型
.局部变量 局_文本1, 文本型
.局部变量 局_文本2, 文本型

局_文本 ＝ 到文本 (HTTP读文件 (“http://www.bwlc.net/bulletin/prevkeno.html”))
返回 (局_文本)

.子程序 正则_匹配开奖数据, 逻辑型, 公开, 本子程序采用【Ｅ正则小助手】生成代码。成功返回匹配数量，失败返回0。
.参数 匹配源文本, 文本型, , 欲被匹配的源文本
.参数 参_开奖数据, 数据类型_开奖数据, 参考 数组
.局部变量 局_正则, 正则表达式, , , 采用正则表达式支持库，无此支持库的请到官方下载。
.局部变量 局_搜索结果, 搜索结果, , "0"
.局部变量 局_匹配数, 整数型, , , 匹配数量
.局部变量 局_计次, 整数型
.局部变量 局_临时文本, 文本型, , "0"
.局部变量 局_计数, 整数型

.如果真 (局_正则.创建 (“<tr class=” ＋ #引号 ＋ “.*?” ＋ #引号 ＋ “>[\s\S]*?<td>([0-9]{6})</td>[\s\S]*?<td>(.*?)</td>[\s\S]*?</tr>”, 假) ＝ 假)
    信息框 (“正则创建失败，请检查正则表达式语句是否有误！”, #错误图标, , )
    返回 (假)

.如果真结束

局_正则.多行模式 ＝ 真
局_搜索结果 ＝ 局_正则.搜索全部 (匹配源文本)
局_匹配数 ＝ 取数组成员数 (局_搜索结果)
' 局_匹配数 ＝ 局_正则.取匹配数量 ()
.如果真 (局_匹配数 ＝ 0)
    信息框 (“匹配失败，请检检查正则语句是否有误，数量：0”, #错误图标, , )
    返回 (假)
.如果真结束


重定义数组 (参_开奖数据, 假, 局_匹配数)
重定义数组 (局_临时文本, 假, 局_匹配数)

.计次循环首 (局_匹配数, 局_计次)  ' 可以在循环内再加一个计次循环，取多个子表达式匹配文本
    ' 输出调试文本 (“匹配文本索引 [” ＋ 到文本 (局_计次) ＋ “] 中的子匹配文本索引 1：” ＋ 局_搜索结果 [局_计次].取子匹配文本 (匹配源文本, 1, ))
    参_开奖数据 [局_计次].期号 ＝ 到整数 (局_搜索结果 [局_计次].取子匹配文本 (匹配源文本, 1, ))
    局_临时文本 [局_计次] ＝ 局_搜索结果 [局_计次].取子匹配文本 (匹配源文本, 2, )
.计次循环尾 ()
' 把局临时文本分割排序
' 调试输出 (参_开奖数据 [1].期号, 局_临时文本 [1])
.如果真 (局_正则.创建 (“([0-9]{2})”, 假) ＝ 假)
    信息框 (“正则创建失败，请检查正则表达式语句是否有误！”, #错误图标, )
    返回 (假)

.如果真结束

.计次循环首 (局_匹配数, 局_计次)
    局_正则.多行模式 ＝ 真
    局_搜索结果 ＝ 局_正则.搜索全部 (局_临时文本 [局_计次])
    局_匹配数 ＝ 取数组成员数 (局_搜索结果)
    .如果真 (局_匹配数 ≠ 20)
        信息框 (“匹配失败，请检检查正则语句是否有误，数量：0”, #错误图标, )
        返回 (假)
    .如果真结束

    .计次循环首 (20, 局_计数)
        参_开奖数据 [局_计次].开奖号码 [局_计数] ＝ 到整数 (局_搜索结果 [局_计数].取子匹配文本 (局_临时文本 [局_计次], 1, ))
    .计次循环尾 ()
    数组排序 (参_开奖数据 [局_计次].开奖号码, 真)
.计次循环尾 ()

返回 (真)
------------上面代码是获取开奖数据，下面代码是处理开奖数据---------------------
.版本 2

.程序集 开奖数据处理

.子程序 计算开奖结果, 逻辑型, 公开
.参数 参_开奖数据, 数据类型_开奖数据, 参考 数组
.参数 参_开奖结果, 数据类型_开奖结果, 参考 数组
.参数 参_A, 整数型, 数组
.参数 参_B, 整数型, 数组
.参数 参_C, 整数型, 数组
.局部变量 局_计数, 整数型
.局部变量 局_计次, 整数型
.局部变量 局_数量, 整数型
.局部变量 局_A, 整数型
.局部变量 局_B, 整数型
.局部变量 局_C, 整数型

局_数量 ＝ 取数组成员数 (参_开奖数据)
.如果真 (局_数量 ＝ 0)
    返回 (假)
.如果真结束

重定义数组 (参_开奖结果, 假, 局_数量)

.计次循环首 (局_数量, 局_计数)
    局_A ＝ 0
    局_B ＝ 0
    局_C ＝ 0

    局_计次 ＝ 取数组成员数 (参_A)
    .如果真 (局_计次 ＝ 0)
        到循环尾 ()
    .如果真结束

    .计次循环首 (局_计次, 局_计次)
        局_A ＝ 局_A ＋ 参_开奖数据 [局_计数].开奖号码 [参_A [局_计次]]
    .计次循环尾 ()

    局_计次 ＝ 取数组成员数 (参_B)
    .如果真 (局_计次 ＝ 0)
        到循环尾 ()
    .如果真结束

    .计次循环首 (局_计次, 局_计次)
        局_B ＝ 局_B ＋ 参_开奖数据 [局_计数].开奖号码 [参_B [局_计次]]
    .计次循环尾 ()

    局_计次 ＝ 取数组成员数 (参_C)
    .如果真 (局_计次 ＝ 0)
        到循环尾 ()
    .如果真结束

    .计次循环首 (局_计次, 局_计次)
        局_C ＝ 局_C ＋ 参_开奖数据 [局_计数].开奖号码 [参_C [局_计次]]
    .计次循环尾 ()

    局_A ＝ 局_A ％ 10
    局_B ＝ 局_B ％ 10
    局_C ＝ 局_C ％ 10

    参_开奖结果 [局_计数].期号 ＝ 参_开奖数据 [局_计数].期号
    参_开奖结果 [局_计数].A ＝ 局_A
    参_开奖结果 [局_计数].B ＝ 局_B
    参_开奖结果 [局_计数].C ＝ 局_C
    参_开奖结果 [局_计数].结果 ＝ 局_A ＋ 局_B ＋ 局_C

.计次循环尾 ()

返回 (真)

3、回到软件，载入刚才的模块，然后做一个时钟周期初始化的子程序：

.版本 2

.子程序 时钟周期初始化
.局部变量 现行时间, 日期时间型
.局部变量 小时, 整数型
.局部变量 分钟, 整数型
.局部变量 秒钟, 整数型
.局部变量 时钟, 整数型


现行时间 ＝ 取现行时间 ()
小时 ＝ 取时间部分 (现行时间, #小时)
分钟 ＝ 取时间部分 (现行时间, #分钟)
秒钟 ＝ 取时间部分 (现行时间, #秒)
.判断开始 (小时 ＜ 9)
    时钟 ＝ ((9 － 小时) × 60 － 分钟) × 60 － 秒钟 ＋ 起始时间

.默认

    时钟 ＝ 时间间隔 － (分钟 × 60 ＋ 秒钟 － 起始时间) ％ 时间间隔

.判断结束
时钟开奖.时钟周期 ＝ 时钟 × 1000
倒计时 ＝ 时钟

大致这样，也可以优化一下。

4、添加自己的算法到软件里面，就做好了。

简单就写这么多，主要的都写出来了，细节太多，大家自己优化一下就可以了。

AD：【此广告位招租】如：联系我们